/* Scores predicted from the SF-12 instrument
	Created by Janel Hanmer in May 2005 */


/*All prediction algorithms use the MCS and PCS scores from the SF-12.  These variables are designated by
 MCS12 and PCS12 

The Sengupta predictions require Age in years (AGE) and gender (Female where 0=male and 1=female)

Replace the set file location with your appropriate file*/

data sf12;
	set 'C:\. . .';
run;

/* Predicted EQ-5D and HUI3 scores.  The EQ-5D weights come from the UK TTO values.
Personal communcation with Peter Franks confirmed using the published sample means, not data sample means
and that this algorithm uses SF-12 version 1.

Franks P, Lubetkin EI, Gold MR, Tancredi DJ. Mapping the SF-12 to Preference-Based Instruments: 
Convergent Validity in a Low-Income, Minority Population. Med Care.  2003;41:1277-1283. */

data sf12;
	set sf12;
Franks03_EQ5D = 0.822 + 0.012*(PCS12-45.8) + 0.008*(MCS12-46.5) -0.00035*(PCS12-45.8)*(PCS12-45.8) - 
	0.00035*(MCS12-46.5)*(MCS12-46.5) - 0.00025*(PCS12-45.8)* (MCS12-46.5);
Franks03_HUI3 = 0.717 + 0.012*(PCS12-45.8) + 0.012*(MCS12 - 46.5) - 0.00029*(MCS12-46.5)*(MCS12-46.5);

run;

/* Predicted HUI3 and VAS scores.  This algorithm is based on SF-12 version 1. I have also included
all terms in Table 3, regardless of significance.  Personal communication with Mike Nichol.  This algorithm
tends to produce very high HUI3 estimates as it was developed with people with low MCS/PCS scores.

Sengupta N, Nichol MB, Wu J, Globe D.  Mapping the SF-12 to the HUI3 and VAS in a Managed Care Population.
Med Care.  2004;42:927-937.  */

data sf12;
	set sf12;

Sengupta_VAS = .2 + .002 * PCS12 + .003 * MCS12 + .00002 * PCS12 * MCS12 + .00007 * PCS12 * PCS12 + 
	.00002 * MCS12 * MCS12 + .0002 * AGE + .008 * Female;

Sengupta_HUI3 = -.784 + .026 * PCS12 + .026 * MCS12 - .0001 * PCS12 * MCS12 - .0001 * PCS12 * PCS12 
	- .0001 * MCS12 * MCS12 - .0009 * AGE + .004 * Female;

run;


/* Predicted EQ-5D scores with UK TTO weighting.  This uses SF-12 version 1 because it is MEPS 2000

Lawrence WF, Fleishman JA.  Predicting the EuroQol EQ-5D Preference Scores from the SF-12 
	Health Survey in a Nationally Representative Sample.  Med Decis Making.  2004;24:160-169 

This algorithm is the 2 variable model from Table 4	*/


data sf12;
	set sf12;
Lawrence_EQ5D = -.3720 + PCS12*.01411 + MCS12*.00967;
run;



/*Predicted EQ-5D scores with UK TTO weighting.  This uses SF-12 version 1 because it is from MEPS 2000

Franks P, Lubetkin EI, Gold MR, Tancredi DJ, Haomiao J.  Mapping the SF-12 to the EuroQol EQ-5D Index 
in a National US Sample.  Med Decis Making.  2004;24:247-254.

From Table 2, SF-12 items only (no demographics) */

data sf12;
	set sf12;
Franks04_EQ5D = .84690 + .01261 * (PCS12 - 49.9) + .00759 * (MCS12 - 51.5) - .00009 * (PCS12 - 49.9) * (PCS12 - 49.9)  
- .00015 * (MCS12 - 51.5) * (MCS12 - 51.5) - .00015 * (MCS12 - 51.5) * (PCS12 - 49.9);
run;


/* Sullivan et al are working on a prediction algorithm from SF-12 version 1 to EQ-5D with US weights
using MEPS data.  I will include it when it is published  */